mirror of
https://github.com/ggerganov/whisper.cpp.git
synced 2025-05-17 16:02:51 +00:00
c774eec709
* Updated models download URL * Updated list of models available All of the high efficiency quantized models are rejected when trying to download. They exist on the server. Let's allow them. * added path prefix for whisper-cli in message to user. The message is misleading if this script is called from another script in a different folder. So the message has to be fixed. * undid download URL change I made earlier. Fixed filepath.Join(urlPath, model) bug. * Undid download URL change I made earlier. Seems that the old URL works but only when provided a model to download. Still doesn't explain why there's a different download URL that also works. Please elucidate in docs. * Fixed URLForModel Function's bug filepath.Join is designed for filesystem paths, and it uses backslashes (\) on Windows. URLs, however, require forward slashes (/), so the use of filepath.Join is inappropriate for constructing URLs. The fmt.Sprintf function ensures that forward slashes are used. * Fixed URL trailing / double slash bug Ensure no double slash by trimming trailing '/' from srcUrl if present * Fixed bad download URL, missing ggml prefix Not sure if that was a bug I introduced but it was trying to download without the prefix. * Added question before downloading all models. Added download size estimate HEAD Requests: Efficiently fetches file sizes without downloading the content. Interactive Workflow: Allows the user to make informed decisions about downloading all models. Safe Defaults: Aborts if the user does not explicitly confirm. * Fixed Unbuffered channel warning. warning in context.go : misuse of unbuffered os.Signal channel as argument to signal. The warning indicates that the unbuffered channel used in signal.Notify in context.go may be misused. In Go, unbuffered channels can cause potential deadlocks if signals are sent faster than they are received. * Fixed download size calculation, download URL prefix bug, added link to models URL for user. The URL formatter was prepending the model name to the formatted model name in the URL * Added logs and exes to gitignore * Delete bindings/go/examples/go-model-download/go-model-download.exe * Delete whisper_build.log
76 lines
1.7 KiB
Batchfile
76 lines
1.7 KiB
Batchfile
@echo off
|
|
|
|
pushd %~dp0
|
|
set models_path=%CD%
|
|
for %%d in (%~dp0..) do set root_path=%%~fd
|
|
popd
|
|
|
|
set argc=0
|
|
for %%x in (%*) do set /A argc+=1
|
|
|
|
set models=tiny tiny-q5_1 tiny-q8_0 ^
|
|
tiny.en tiny.en-q5_1 tiny.en-q8_0 ^
|
|
base base-q5_1 base-q8_0 ^
|
|
base.en base.en-q5_1 base.en-q8_0 ^
|
|
small small-q5_1 small-q8_0 ^
|
|
small.en small.en-q5_1 small.en-q8_0 ^
|
|
medium medium-q5_0 medium-q8_0 ^
|
|
medium.en medium.en-q5_0 medium.en-q8_0 ^
|
|
large-v1 ^
|
|
large-v2 large-v2-q5_0 large-v2-q8_0 ^
|
|
large-v3 large-v3-q5_0 ^
|
|
large-v3-turbo large-v3-turbo-q5_0 large-v3-turbo-q8_0
|
|
|
|
if %argc% neq 1 (
|
|
echo.
|
|
echo Usage: download-ggml-model.cmd model
|
|
CALL :list_models
|
|
goto :eof
|
|
)
|
|
|
|
set model=%1
|
|
|
|
for %%b in (%models%) do (
|
|
if "%%b"=="%model%" (
|
|
CALL :download_model
|
|
goto :eof
|
|
)
|
|
)
|
|
|
|
echo Invalid model: %model%
|
|
CALL :list_models
|
|
goto :eof
|
|
|
|
:download_model
|
|
echo Downloading ggml model %model%...
|
|
|
|
cd "%models_path%"
|
|
|
|
if exist "ggml-%model%.bin" (
|
|
echo Model %model% already exists. Skipping download.
|
|
goto :eof
|
|
)
|
|
|
|
PowerShell -NoProfile -ExecutionPolicy Bypass -Command "Start-BitsTransfer -Source https://huggingface.co/ggerganov/whisper.cpp/resolve/main/ggml-%model%.bin -Destination ggml-%model%.bin"
|
|
|
|
if %ERRORLEVEL% neq 0 (
|
|
echo Failed to download ggml model %model%
|
|
echo Please try again later or download the original Whisper model files and convert them yourself.
|
|
goto :eof
|
|
)
|
|
|
|
echo Done! Model %model% saved in %root_path%\models\ggml-%model%.bin
|
|
echo You can now use it like this:
|
|
echo %~dp0build\bin\Release\whisper-cli.exe -m %root_path%\models\ggml-%model%.bin -f %root_path%\samples\jfk.wav
|
|
|
|
goto :eof
|
|
|
|
:list_models
|
|
echo.
|
|
echo Available models:
|
|
(for %%a in (%models%) do (
|
|
echo %%a
|
|
))
|
|
echo.
|
|
exit /b
|