mirror of
https://github.com/corda/corda.git
synced 2024-12-19 13:08:04 +00:00
1e12aebe0a
* Skeleton plugin. * Implement Gradle api-scanner plugin, and apply it. * Generate API documentation for any jar without a classifier. * Fix usage of smokeTests classifier. * Tweak Gradle API usage. * Upgrade to fast-classpath-scanner 2.7.0 * Include interfaces and more modifiers in the class description. * Allow system classes to be supertypes and implemented interfaces. * Make API Scanner plugin configuration tweakable via build.gradle. * Add a miserable amount of unit testing. * Sort methods and fields using their natural comparators. Way easier! * Add README for api-scanner plugin. * Add @OutputFiles to ScanApiTask. * Rename ScanApiTask to ScanApi. * Allow the ScanApi task to be disabled. * WIP: Create a top-level GenerateApi task to collate the ScanApi output. * Exclude package-private classes, as well as bridge/synthetic methods. * Replace "End of Class" delimiter with '##'. * Don't scan modules whose API is still "in flux". * Include constructors in the API definitions. * Finish implementation of GenerateApi task. * Update README to include GenerateApi task. * Filter out Kotlin's "internal" methods. * Assign "fatjar" classifier to the fat jar artifact. * Enhance README for GenerateApi. * Explain effect of api-scanner plugin, and link to Corda's API strategy. * Tweak README * Exclude synthetic Kotlin classes by analysing @Metadata. * Allow us to exclude some classes explicitly from the API.
108 lines
3.2 KiB
Groovy
108 lines
3.2 KiB
Groovy
apply plugin: 'kotlin'
|
|
apply plugin: 'kotlin-jpa'
|
|
apply plugin: 'net.corda.plugins.quasar-utils'
|
|
apply plugin: 'net.corda.plugins.publish-utils'
|
|
apply plugin: 'net.corda.plugins.api-scanner'
|
|
apply plugin: 'com.jfrog.artifactory'
|
|
|
|
description 'Corda core'
|
|
|
|
buildscript {
|
|
repositories {
|
|
mavenCentral()
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
|
|
testCompile "junit:junit:$junit_version"
|
|
testCompile "commons-fileupload:commons-fileupload:$fileupload_version"
|
|
|
|
// Guava: Google test library (collections test suite)
|
|
testCompile "com.google.guava:guava-testlib:$guava_version"
|
|
|
|
// Bring in the MockNode infrastructure for writing protocol unit tests.
|
|
testCompile project(":node")
|
|
testCompile project(":node-driver")
|
|
|
|
compile "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
|
|
compile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
|
|
testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
|
|
|
|
// Quasar, for suspendable fibres.
|
|
compileOnly "co.paralleluniverse:quasar-core:$quasar_version:jdk8"
|
|
|
|
// Thread safety annotations
|
|
compile "com.google.code.findbugs:jsr305:3.0.1"
|
|
|
|
// Log4J: logging framework (ONLY explicitly referenced by net.corda.core.utilities.Logging.kt)
|
|
compile "org.apache.logging.log4j:log4j-core:${log4j_version}"
|
|
|
|
// SLF4J: commons-logging bindings for a SLF4J back end
|
|
compile "org.slf4j:jcl-over-slf4j:$slf4j_version"
|
|
compile "org.slf4j:slf4j-api:$slf4j_version"
|
|
|
|
// AssertJ: for fluent assertions for testing
|
|
testCompile "org.assertj:assertj-core:${assertj_version}"
|
|
|
|
// Guava: Google utilities library.
|
|
testCompile "com.google.guava:guava:$guava_version"
|
|
|
|
// RxJava: observable streams of events.
|
|
compile "io.reactivex:rxjava:$rxjava_version"
|
|
|
|
// Apache JEXL: An embeddable expression evaluation library.
|
|
// This may be temporary until we experiment with other ways to do on-the-fly contract specialisation via an API.
|
|
compile "org.apache.commons:commons-jexl3:3.0"
|
|
|
|
// For JSON
|
|
compile "com.fasterxml.jackson.core:jackson-databind:${jackson_version}"
|
|
|
|
// Java ed25519 implementation. See https://github.com/str4d/ed25519-java/
|
|
compile "net.i2p.crypto:eddsa:$eddsa_version"
|
|
|
|
// Bouncy castle support needed for X509 certificate manipulation
|
|
compile "org.bouncycastle:bcprov-jdk15on:${bouncycastle_version}"
|
|
compile "org.bouncycastle:bcpkix-jdk15on:${bouncycastle_version}"
|
|
|
|
// JPA 2.1 annotations.
|
|
compile "org.hibernate.javax.persistence:hibernate-jpa-2.1-api:1.0.0.Final"
|
|
}
|
|
|
|
// TODO Consider moving it to quasar-utils in the future (introduced with PR-1388)
|
|
task copyQuasarJar(type: Copy) {
|
|
from configurations.quasar
|
|
into "$project.rootProject.projectDir/lib"
|
|
rename { filename -> "quasar.jar"}
|
|
}
|
|
|
|
jar.finalizedBy(copyQuasarJar)
|
|
|
|
configurations {
|
|
testArtifacts.extendsFrom testRuntime
|
|
}
|
|
|
|
task testJar(type: Jar) {
|
|
classifier "tests"
|
|
from sourceSets.test.output
|
|
}
|
|
|
|
artifacts {
|
|
testArtifacts testJar
|
|
}
|
|
|
|
jar {
|
|
baseName 'corda-core'
|
|
}
|
|
|
|
scanApi {
|
|
excludeClasses = [
|
|
// Kotlin should probably have declared this class as "synthetic".
|
|
"net.corda.core.Utils\$toFuture\$1\$subscription\$1"
|
|
]
|
|
}
|
|
|
|
publish {
|
|
name jar.baseName
|
|
}
|