mirror of
https://github.com/corda/corda.git
synced 2024-12-21 05:53:23 +00:00
47068e6b7a
* Upgrade gradle plugin; add target version attribute to finance and sample cordapps. * Remove '-SNAPSHOT' from gradlePluginsVersion. * Fix naming. * Update docs. * Respond to feedback. * Fix irs demo * Fix more samples * Fix more samples * Fix deployNodes * Fix deployNodes * more fixes * fix simm valuation * more fixes * more fixes * more fixes * more fixes * Publication should have *nothing* to do with cordformation and deployNodes. Remove it! And if this exposes a bug then "so be it". * Disable CorDapp signing for Cordapp Configuration and Network Verifier. * Disable CorDapp signing for SIMM Valuation Demo. * Remove remaining publishing nonsense from samples. * Workarounds fpr cordapp-configuration, network-verifier and simm-valuation-demo: JarSigner rejects jars with duplicates inside, so remove them. * Upgrade to Gradle plugin 4.0.32 and reenable CorDapp signing for samples.
98 lines
2.7 KiB
Groovy
98 lines
2.7 KiB
Groovy
apply plugin: 'kotlin'
|
|
// Java Persistence API support: create no-arg constructor
|
|
// see: http://stackoverflow.com/questions/32038177/kotlin-with-jpa-default-constructor-hell
|
|
apply plugin: 'kotlin-jpa'
|
|
apply plugin: CanonicalizerPlugin
|
|
apply plugin: 'net.corda.plugins.publish-utils'
|
|
apply plugin: 'net.corda.plugins.quasar-utils'
|
|
apply plugin: 'net.corda.plugins.cordapp'
|
|
apply plugin: 'com.jfrog.artifactory'
|
|
|
|
description 'Corda finance modules'
|
|
|
|
sourceSets {
|
|
integrationTest {
|
|
kotlin {
|
|
compileClasspath += main.output + test.output
|
|
runtimeClasspath += main.output + test.output
|
|
srcDir file('src/integration-test/kotlin')
|
|
}
|
|
resources {
|
|
srcDir file('src/integration-test/resources')
|
|
}
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
// Note the :finance module is a CorDapp in its own right
|
|
// and CorDapps using :finance features should use 'cordapp' not 'compile' linkage.
|
|
cordaCompile project(':core')
|
|
cordaCompile project(':confidential-identities')
|
|
|
|
// TODO Remove this once we have app configs
|
|
compile "com.typesafe:config:$typesafe_config_version"
|
|
|
|
// For JSON
|
|
compile "com.fasterxml.jackson.core:jackson-databind:${jackson_version}"
|
|
|
|
testCompile project(':test-utils')
|
|
testCompile project(path: ':core', configuration: 'testArtifacts')
|
|
testCompile "junit:junit:$junit_version"
|
|
|
|
// AssertJ: for fluent assertions for testing
|
|
testCompile "org.assertj:assertj-core:$assertj_version"
|
|
}
|
|
|
|
configurations {
|
|
testArtifacts.extendsFrom testRuntime
|
|
integrationTestCompile.extendsFrom testCompile
|
|
integrationTestRuntime.extendsFrom testRuntime
|
|
}
|
|
|
|
task testJar(type: Jar) {
|
|
classifier "tests"
|
|
from sourceSets.test.output
|
|
}
|
|
|
|
task integrationTest(type: Test, dependsOn: []) {
|
|
testClassesDirs = sourceSets.integrationTest.output.classesDirs
|
|
classpath = sourceSets.integrationTest.runtimeClasspath
|
|
}
|
|
|
|
artifacts {
|
|
testArtifacts testJar
|
|
}
|
|
|
|
jar {
|
|
baseName 'corda-finance'
|
|
exclude "META-INF/*.DSA"
|
|
exclude "META-INF/*.RSA"
|
|
exclude "META-INF/*.SF"
|
|
exclude "META-INF/*.MF"
|
|
exclude "META-INF/LICENSE"
|
|
exclude "META-INF/NOTICE"
|
|
|
|
manifest {
|
|
attributes(
|
|
"Manifest-Version": "1.0",
|
|
"Specification-Title": description,
|
|
"Specification-Version": version,
|
|
"Specification-Vendor": "Corda Open Source",
|
|
"Implementation-Title": "$group.$baseName",
|
|
)
|
|
}
|
|
}
|
|
|
|
cordapp {
|
|
info {
|
|
name "net/corda/finance"
|
|
vendor "Corda Open Source"
|
|
targetPlatformVersion corda_platform_version.toInteger()
|
|
minimumPlatformVersion 1
|
|
}
|
|
}
|
|
|
|
publish {
|
|
name jar.baseName
|
|
}
|