mirror of
https://github.com/corda/corda.git
synced 2024-12-19 13:08:04 +00:00
47068e6b7a
* Upgrade gradle plugin; add target version attribute to finance and sample cordapps. * Remove '-SNAPSHOT' from gradlePluginsVersion. * Fix naming. * Update docs. * Respond to feedback. * Fix irs demo * Fix more samples * Fix more samples * Fix deployNodes * Fix deployNodes * more fixes * fix simm valuation * more fixes * more fixes * more fixes * more fixes * Publication should have *nothing* to do with cordformation and deployNodes. Remove it! And if this exposes a bug then "so be it". * Disable CorDapp signing for Cordapp Configuration and Network Verifier. * Disable CorDapp signing for SIMM Valuation Demo. * Remove remaining publishing nonsense from samples. * Workarounds fpr cordapp-configuration, network-verifier and simm-valuation-demo: JarSigner rejects jars with duplicates inside, so remove them. * Upgrade to Gradle plugin 4.0.32 and reenable CorDapp signing for samples.
113 lines
3.8 KiB
Groovy
113 lines
3.8 KiB
Groovy
buildscript {
|
|
ext {
|
|
springBootVersion = '1.5.10.RELEASE'
|
|
}
|
|
repositories {
|
|
mavenCentral()
|
|
}
|
|
dependencies {
|
|
classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
|
|
classpath "io.spring.gradle:dependency-management-plugin:1.0.4.RELEASE"
|
|
}
|
|
}
|
|
|
|
// Spring Boot plugin adds a numerous hardcoded dependencies in the version much lower then Corda expects
|
|
// causing the problems in runtime. Those can be changed by manipulating above properties
|
|
// See https://github.com/spring-gradle-plugins/dependency-management-plugin/blob/master/README.md#changing-the-value-of-a-version-property
|
|
ext['artemis.version'] = "$artemis_version"
|
|
ext['hibernate.version'] = "$hibernate_version"
|
|
ext['selenium.version'] = "$selenium_version"
|
|
ext['jackson.version'] = "$jackson_version"
|
|
ext['dropwizard-metrics.version'] = "$metrics_version"
|
|
ext['mockito.version'] = "$mockito_version"
|
|
|
|
apply plugin: 'kotlin'
|
|
apply plugin: 'idea'
|
|
apply plugin: 'org.springframework.boot'
|
|
apply plugin: 'net.corda.plugins.quasar-utils'
|
|
apply plugin: 'application'
|
|
|
|
mainClassName = 'net.corda.irs.IRSDemo'
|
|
|
|
sourceSets {
|
|
integrationTest {
|
|
kotlin {
|
|
compileClasspath += main.output + test.output
|
|
runtimeClasspath += main.output + test.output
|
|
srcDir file('src/integration-test/kotlin')
|
|
}
|
|
}
|
|
systemTest {
|
|
kotlin {
|
|
compileClasspath += main.output + test.output
|
|
runtimeClasspath += main.output + test.output
|
|
srcDir file('src/system-test/kotlin')
|
|
}
|
|
}
|
|
}
|
|
|
|
configurations {
|
|
integrationTestCompile.extendsFrom testCompile
|
|
integrationTestRuntime.extendsFrom testRuntime
|
|
demoArtifacts.extendsFrom testRuntime
|
|
systemTestCompile.extendsFrom testCompile
|
|
}
|
|
|
|
repositories {
|
|
maven {
|
|
url 'https://dl.bintray.com/palantir/releases' // docker-compose-rule is published on bintray
|
|
}
|
|
maven { url 'https://jitpack.io' }
|
|
}
|
|
|
|
dependencies {
|
|
compile group: 'commons-io', name: 'commons-io', version: '2.5'
|
|
compile project(path: ":samples:irs-demo:cordapp", configuration: "demoArtifacts")
|
|
compile project(":samples:irs-demo:web")
|
|
compile('org.springframework.boot:spring-boot-starter-web') {
|
|
exclude module: "spring-boot-starter-logging"
|
|
exclude module: "logback-classic"
|
|
}
|
|
|
|
testCompile project(':node-driver')
|
|
testCompile "junit:junit:$junit_version"
|
|
testCompile "org.assertj:assertj-core:${assertj_version}"
|
|
|
|
integrationTestCompile project(path: ":samples:irs-demo:web", configuration: "demoArtifacts")
|
|
testCompile "com.palantir.docker.compose:docker-compose-rule-junit4:$docker_compose_rule_version"
|
|
testCompile "org.seleniumhq.selenium:selenium-java:$selenium_version"
|
|
testCompile "com.github.detro:ghostdriver:$ghostdriver_version"
|
|
}
|
|
|
|
bootRepackage {
|
|
enabled = false
|
|
}
|
|
|
|
task integrationTest(type: Test, dependsOn: []) {
|
|
testClassesDirs = sourceSets.integrationTest.output.classesDirs
|
|
classpath = sourceSets.integrationTest.runtimeClasspath
|
|
}
|
|
|
|
evaluationDependsOn("cordapp")
|
|
evaluationDependsOn("web")
|
|
|
|
task systemTest(type: Test, dependsOn: ["cordapp:prepareDockerNodes", "web:generateDockerCompose"]) {
|
|
testClassesDirs = sourceSets.systemTest.output.classesDirs
|
|
classpath = sourceSets.systemTest.runtimeClasspath
|
|
|
|
systemProperty "CORDAPP_DOCKER_COMPOSE", tasks.getByPath("cordapp:prepareDockerNodes").dockerComposePath.toString()
|
|
systemProperty "WEB_DOCKER_COMPOSE", tasks.getByPath("web:generateDockerCompose").dockerComposePath.toString()
|
|
|
|
def phantomJsPath = System.getProperty("phantomjs.binary.path") ?: System.getenv("PHANTOMJS_BINARY_PATH")
|
|
if (phantomJsPath != null) {
|
|
systemProperty "phantomjs.binary.path", phantomJsPath
|
|
}
|
|
}
|
|
|
|
idea {
|
|
module {
|
|
downloadJavadoc = true // defaults to false
|
|
downloadSources = true
|
|
}
|
|
}
|