mirror of
https://github.com/corda/corda.git
synced 2024-12-30 17:57:02 +00:00
c545a58c1d
* Initial host server skeleton. * Create IASProxy project, and skeleton for attestation host. * Fix up tests * Extend attestation host skeleton, and make test ports configurable. * Enhance MockIAS to make pseManifestStatus optional. * Make IASProxy endpoints asynchronous. * Add sub-modules for challenger and for common code. * Create integration test for host's provisioning endpoint. * Flesh out attestation challenger WAR. * Package refactoring, to be more Java9 friendly. * Refactor more messages into attestation-common. * Remove our private key from the repository. * Declare an empty PSE Manifest to be invalid. * Fix basic integration test issues for challenger and host. * Integrate keystore scripts into the build properly. * Name keystore targets explicitly for Gradle. * Allow HTTP conversation between Challenger, Host and ISV using session ID. * Add MockHost for challenger's integration tests. * Reconcile HTTP port numbers between Phase1 and Phase2 components. * Remove elements that can be inherited from root project. * Add placeholder README. * Add convenient extension functions to ObjectMapper. * Extend integration test coverage for challenger/host/isv. * Catch IOException from HttpClient for challenger. * Integrate host sub-module with remote-attestation project. * Begin integrating host/enclave code from Phase I. * Rename challenger's HTTP endpoint. * Generate keystore for challenger "on the fly". * Add native JNI code for accessing the SGX enclave. * Point Gradle to the correct enclave object. * Fixes for generating a Quote for this enclave. * Return the IAS report to the challenger for verification. * Begin populating the challenger's AttestationResponse message. * Enable the challenger to pass encrypted secrets into the enclave. * Align challenger, host and isv ports. * Refactor challenger as a fat-jar application. * AttestationResponse is not shared, so refactor into challenger. * Move HttpClientContext objects into HttpClient blocks. * Remove unused Message2 and Message3 objects. * Add realistic dummy value for reportID from IAS. * Small tidy-up on attestation host. * First set of review comments. * Add missing exception message. * Update location of environment file. * Use empty mock revocation lists by default. * Improve logging and add "happy path" test for provisioning secrets. * Update Gradle files so that we can run attestation-host from IntelliJ. * The platformInfo field from IAS can be null, so allow this. Also protect other JNI pointer parameters from NPE. * Allow Gradle to build hardware enclave.
151 lines
4.7 KiB
Groovy
151 lines
4.7 KiB
Groovy
version = '0.1'
|
|
|
|
buildscript {
|
|
ext.dokka_version = "0.9.15"
|
|
|
|
ext.nativeBuildDir = "$projectDir/native/build"
|
|
ext.enclaveBuildDir = "$projectDir/../enclave/build"
|
|
|
|
if (!project.hasProperty("debug")) {
|
|
ext.debug = false
|
|
} else {
|
|
ext.debug = (ext.debug == "1" || ext.debug == "yes" || ext.debug == "true")
|
|
}
|
|
|
|
if (!project.hasProperty("debugPort")) {
|
|
ext.debugPort = 5005
|
|
} else {
|
|
ext.debugPort = Integer.parseInt(ext.debugPort.toString())
|
|
}
|
|
|
|
if (ext.debug) {
|
|
ext.debugArgs = "-agentlib:jdwp=transport=dt_socket,server=y,suspend=y,timeout=10000,address=$debugPort"
|
|
} else {
|
|
ext.debugArgs = "-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=$debugPort"
|
|
}
|
|
|
|
repositories {
|
|
mavenLocal()
|
|
mavenCentral()
|
|
jcenter()
|
|
}
|
|
|
|
dependencies {
|
|
classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokka_version"
|
|
}
|
|
}
|
|
|
|
apply from: 'utilities.gradle'
|
|
apply plugin: 'kotlin'
|
|
apply plugin: 'application'
|
|
apply plugin: 'org.jetbrains.dokka'
|
|
|
|
mainClassName = 'net.corda.sgx.cli.Program'
|
|
description "Client side of SGX remote attestation process"
|
|
|
|
configurations {
|
|
integrationTestCompile.extendsFrom testCompile
|
|
integrationTestRuntime.extendsFrom testRuntime
|
|
}
|
|
|
|
sourceSets {
|
|
integrationTest {
|
|
kotlin {
|
|
compileClasspath += main.output + test.output
|
|
runtimeClasspath += main.output + test.output
|
|
srcDir file('src/integration-test/kotlin')
|
|
}
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
|
|
testCompile "junit:junit:$junit_version"
|
|
testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
|
|
|
|
compile "com.fasterxml.jackson.core:jackson-core:$jackson_version"
|
|
compile "com.fasterxml.jackson.core:jackson-databind:$jackson_version"
|
|
compile "com.fasterxml.jackson.core:jackson-annotations:$jackson_version"
|
|
compile "com.fasterxml.jackson.datatype:jackson-datatype-jsr310:$jackson_version"
|
|
|
|
compile "org.apache.httpcomponents:httpclient:$httpclient_version"
|
|
compile "org.apache.logging.log4j:log4j-slf4j-impl:$log4j_version"
|
|
compile "org.apache.logging.log4j:log4j-core:$log4j_version"
|
|
runtime "org.apache.logging.log4j:log4j-web:$log4j_version"
|
|
compile "org.slf4j:jcl-over-slf4j:$slf4j_version"
|
|
}
|
|
|
|
dokka {
|
|
outputFormat = 'html'
|
|
outputDirectory = "$buildDir/javadoc"
|
|
}
|
|
|
|
task integrationTest(type: Test) {
|
|
testClassesDirs = sourceSets.integrationTest.output.classesDirs
|
|
classpath = sourceSets.integrationTest.runtimeClasspath
|
|
}
|
|
|
|
tasks.withType(Test) {
|
|
systemProperty "java.library.path", "$nativeBuildDir"
|
|
systemProperty "corda.sgx.enclave.path", "$enclaveBuildDir"
|
|
jvmArgs "$debugArgs"
|
|
}
|
|
|
|
task cleanEnclave(type: Exec) {
|
|
commandLine containerArgs("enclave", "clean")
|
|
}
|
|
|
|
task cleanJniLibrary(type: Exec) {
|
|
commandLine containerArgs("host/native", "clean")
|
|
}
|
|
|
|
clean.dependsOn.addAll 'cleanEnclave', 'cleanJniLibrary'
|
|
|
|
task buildEnclave(type: Exec) {
|
|
commandLine containerArgs("enclave", "all")
|
|
}
|
|
|
|
task buildJniLibrary(type: Exec, dependsOn: ['buildEnclave', 'classes']) {
|
|
commandLine containerArgs("host/native", "all")
|
|
}
|
|
|
|
task runFlow(type: Exec, dependsOn: ['buildJniLibrary']) {
|
|
commandLine runArgs(["java"], ["net.corda.sgx.cli.Program"])
|
|
}
|
|
|
|
task runFlowWithNativeDebugger(type: Exec, dependsOn: ['buildJniLibrary']) {
|
|
commandLine runArgs(["gdb", "--args", "java"], ["net.corda.sgx.cli.Program"])
|
|
}
|
|
|
|
task runFlowWithNativeSgxDebugger(type: Exec, dependsOn: ['buildJniLibrary']) {
|
|
commandLine runArgs(["sgx-gdb", "--args", "java"], ["net.corda.sgx.cli.Program"])
|
|
}
|
|
|
|
task runFlowWithNativeDebugServer(type: Exec, dependsOn: ['buildJniLibrary']) {
|
|
commandLine runArgs(["gdbserver", "localhost:2000", "java"], ["net.corda.sgx.cli.Program"])
|
|
}
|
|
|
|
task runUnitTestsInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "unit-tests") }
|
|
}
|
|
|
|
task runIntegrationTestsInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "integration-tests") }
|
|
}
|
|
|
|
task runFlowInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "run") }
|
|
}
|
|
|
|
task debugUnitTestsInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "DEBUG=1", "unit-tests") }
|
|
}
|
|
|
|
task debugIntegrationTestsInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "DEBUG=1", "integration-tests") }
|
|
}
|
|
|
|
task debugFlowInContainer(type: Task, dependsOn: ['buildJniLibrary']) {
|
|
doLast { containerDebugWait("$projectDir", "host", "DEBUG=1", "run") }
|
|
}
|