mirror of
https://github.com/corda/corda.git
synced 2024-12-22 14:22:28 +00:00
28852ce47d
* NOTICK: Corda 4.3-RC01 Created first release candidate of Corda 4.3 - RC01. * CORDA-3141: Add GracefulReconnect callbacks which allow logic to be performed when RPC disconnects unexpectedly (#5430) Also removed potential for growing stack trace on reconnects. * CORDA-2050 Upgrade Corda to Java 11 (compatibility mode) (#5356) Upgrade Corda to run with Java 11 (compatibility mode) - see https://github.com/corda/corda/pull/5356 * ENT-4198 Adding legal text Signed-off-by: Ed Prosser <edward.prosser@r3.com> * TM-29 new baseline for 4.3 since new debt has been added with the last few commits (#5487) * TM-23 compileAll task to compile all code (#5490) * Add simple compileAll task to be used by warning check * lazy configure compileAll * TM-32 Merge OS 4.3 into 4.4 * TM-32 fixed detekt issue * Downgrade Dokka back to 0.9.17 due to failing docs_builder. * add ability to group test types together (#5459) * add ability to group test types together * add ability to specify podCount for use in parallel testing * remove compiler xml * add Jenkinsfile to enable scanning * trigger build * add ability to specify what docker tag to use from outside of the build * fix docker work dir * fix pipeline syntax issues * use environment rather than `def` * move agent restrictor outside of stages block * use steps block * more pipeline syntax fixes * even more pipeline syntax fixes * even more pipeline syntax fixes * add kubenetize as property to image build * move clear of docker image to end of build rather than start to prevent colocated builds * escape dollar on docker image remove command * attempt to kill all existing jobs * fix compile issue due to killall_jobs * fix compile issue due to killall_jobs pt2 * fix spelling * make all variables environment variables * add logic to delete images locally after pushing * wrap testing phase with try / finally so that junit reports are always evaluated * change the behaviour around post build actions * break implicit link between testing phase and image building phase, allowing testing to occur without a rebuild and push of image * prepend registry name to provided tag * allow tasks to specify whether they wish to stream output from containers * add timestamps directive to Jenkinsfile to have timing info on output * make KubesTest resilient against transient pod failures in k8s * increase CPU request * add logic to allow specifying container resource requests * attempt to run unit and integration tests in parallel * change unit tests to use 3 cores to allow co-location on 8c machines * join grouped tests together to give pod meaningful name * add step to renew token with GKE * change renew step to use pods instead of nodes * fix bug where memory request is not correctly passed to pod * disable unit tests for now * [CORDA-2368] Added exception handling for missing files that displays appropriate messages rather than defaulting to file names. (#5472) * NOTIK Minor adjustments to Detekt rules to reflect current working practises (#5498) * Minor adjustments to rules to reflect current working practises (including IntelliJ code style alignment) * Adjust another rule in line with existing code style. * rebaseline with changed detekt ruleset * rebaseline with NodeStartup changes
92 lines
2.9 KiB
Groovy
92 lines
2.9 KiB
Groovy
// JDK 11 JavaFX
|
|
plugins {
|
|
id 'org.openjfx.javafxplugin' version '0.0.7' apply false
|
|
}
|
|
|
|
if (JavaVersion.current().isJava9Compatible()) {
|
|
apply plugin: 'org.openjfx.javafxplugin'
|
|
javafx {
|
|
version = "11.0.2"
|
|
modules = ['javafx.controls',
|
|
'javafx.fxml'
|
|
]
|
|
}
|
|
}
|
|
apply plugin: 'kotlin'
|
|
apply plugin: 'net.corda.plugins.quasar-utils'
|
|
apply plugin: 'net.corda.plugins.publish-utils'
|
|
apply plugin: 'com.jfrog.artifactory'
|
|
|
|
description 'Corda client JavaFX modules'
|
|
|
|
//noinspection GroovyAssignabilityCheck
|
|
configurations {
|
|
integrationTestCompile.extendsFrom testCompile
|
|
integrationTestRuntime.extendsFrom testRuntime
|
|
}
|
|
|
|
sourceSets {
|
|
integrationTest {
|
|
kotlin {
|
|
compileClasspath += main.output + test.output
|
|
runtimeClasspath += main.output + test.output
|
|
srcDir file('src/integration-test/kotlin')
|
|
}
|
|
}
|
|
}
|
|
|
|
// To find potential version conflicts, run "gradle htmlDependencyReport" and then look in
|
|
// build/reports/project/dependencies/index.html for green highlighted parts of the tree.
|
|
|
|
dependencies {
|
|
compile project(':core')
|
|
compile project(':finance:contracts')
|
|
compile project(':finance:workflows')
|
|
compile project(':client:rpc')
|
|
|
|
compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
|
|
compile "com.google.guava:guava:$guava_version"
|
|
|
|
// ReactFX: Functional reactive UI programming.
|
|
compile 'org.reactfx:reactfx:2.0-M5'
|
|
compile 'org.fxmisc.easybind:easybind:1.0.3'
|
|
|
|
// Artemis Client: ability to connect to an Artemis broker and control it.
|
|
// TODO: remove the forced update of commons-collections and beanutils when artemis updates them
|
|
compile "org.apache.commons:commons-collections4:${commons_collections_version}"
|
|
compile "commons-beanutils:commons-beanutils:${beanutils_version}"
|
|
compile "org.apache.activemq:artemis-core-client:${artemis_version}"
|
|
|
|
// Unit testing helpers.
|
|
testImplementation "org.junit.jupiter:junit-jupiter-api:${junit_jupiter_version}"
|
|
testImplementation "junit:junit:$junit_version"
|
|
|
|
testRuntimeOnly "org.junit.vintage:junit-vintage-engine:${junit_vintage_version}"
|
|
testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junit_jupiter_version}"
|
|
testRuntimeOnly "org.junit.platform:junit-platform-launcher:${junit_platform_version}"
|
|
|
|
testCompile "org.assertj:assertj-core:${assertj_version}"
|
|
|
|
testCompile project(':test-utils')
|
|
|
|
// Integration test helpers
|
|
integrationTestCompile "junit:junit:$junit_version"
|
|
integrationTestCompile project(':node-driver')
|
|
}
|
|
|
|
task integrationTest(type: Test) {
|
|
testClassesDirs = sourceSets.integrationTest.output.classesDirs
|
|
classpath = sourceSets.integrationTest.runtimeClasspath
|
|
}
|
|
|
|
jar {
|
|
baseName 'corda-jfx'
|
|
manifest {
|
|
attributes 'Automatic-Module-Name': 'net.corda.client.jfx'
|
|
}
|
|
}
|
|
|
|
publish {
|
|
name jar.baseName
|
|
}
|