mirror of
https://github.com/corda/corda.git
synced 2024-12-18 20:47:57 +00:00
caeafb8201
* ENT-6357: Deserialize LedgerTransaction elements for each Contract.verify(). * Lock the LedgerTransaction and NetworkParameters objects down for contract verification. * Refactor BasicVerifier to be package private instead of public. * Simplify verifyConstraints() operation. * Review fixes: replace HashSet with LinkedHashSet, and add signing parties to commands via mapIndexed. * Ensure tests also run notary nodes "out of process". * Streamline SerializationContext switching. * Cache deserialised cryptographic instances during contract verification. * Invoke Class.forName() instead of ClassLoader.loadClass() to reduce contention on the system classloader's lock. * Deserialization cache key now pre-computes its hash code. * Allow AttachmentsClassLoader to be used concurrently. * Cache all Envelope objects for reuse during contract verification. * Generate CertPathProxy hash code using conventional algorithm. * Adjust CustomSerializer.Proxy to allow better access to SerializationContext.
84 lines
2.5 KiB
Groovy
84 lines
2.5 KiB
Groovy
plugins {
|
|
id 'org.jetbrains.kotlin.jvm'
|
|
id 'net.corda.plugins.publish-utils'
|
|
id 'com.jfrog.artifactory'
|
|
id 'java-library'
|
|
id 'idea'
|
|
}
|
|
|
|
// The DJVM only supports Java 8 byte-code, so the tests must
|
|
// be compiled for Java 8. The main artifact is only compiled
|
|
// for Java 8 because it belongs to "Open Core".
|
|
apply from: "${rootProject.projectDir}/java8.gradle"
|
|
|
|
description 'Serialization support for the DJVM'
|
|
|
|
configurations {
|
|
sandboxTesting {
|
|
canBeConsumed = false
|
|
}
|
|
jdkRt {
|
|
canBeConsumed = false
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
api project(':core')
|
|
api project(':serialization')
|
|
api "net.corda.djvm:corda-djvm:$djvm_version"
|
|
api 'org.jetbrains.kotlin:kotlin-stdlib-jdk8'
|
|
implementation 'org.jetbrains.kotlin:kotlin-reflect'
|
|
implementation(project(':serialization-djvm:deserializers')) {
|
|
transitive = false
|
|
}
|
|
|
|
testImplementation "org.junit.jupiter:junit-jupiter-api:$junit_jupiter_version"
|
|
testImplementation "org.junit.jupiter:junit-jupiter-params:$junit_jupiter_version"
|
|
testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junit_jupiter_version"
|
|
|
|
// Test utilities
|
|
testImplementation "org.assertj:assertj-core:$assertj_version"
|
|
testRuntimeOnly "org.apache.logging.log4j:log4j-slf4j-impl:$log4j_version"
|
|
jdkRt "net.corda:deterministic-rt:$deterministic_rt_version"
|
|
|
|
// The DJVM will need this classpath to run the unit tests.
|
|
sandboxTesting files(sourceSets.getByName("test").output)
|
|
sandboxTesting project(':serialization-djvm:deserializers')
|
|
sandboxTesting project(path: ':serialization-deterministic', configuration: 'deterministicArtifacts')
|
|
sandboxTesting "org.slf4j:slf4j-nop:$slf4j_version"
|
|
}
|
|
|
|
jar {
|
|
archiveBaseName = 'corda-serialization-djvm'
|
|
archiveClassifier = ''
|
|
manifest {
|
|
attributes('Automatic-Module-Name': 'net.corda.serialization.djvm')
|
|
attributes('Sealed': true)
|
|
}
|
|
}
|
|
|
|
tasks.withType(Javadoc).configureEach {
|
|
// We have no public or protected Java classes to document.
|
|
enabled = false
|
|
}
|
|
|
|
tasks.withType(Test).configureEach {
|
|
useJUnitPlatform()
|
|
systemProperty 'deterministic-rt.path', configurations.jdkRt.asPath
|
|
systemProperty 'sandbox-libraries.path', configurations.sandboxTesting.asPath
|
|
|
|
// Configure the host timezone to match the DJVM's.
|
|
systemProperty 'user.timezone', 'UTC'
|
|
}
|
|
|
|
publish {
|
|
name jar.archiveBaseName
|
|
}
|
|
|
|
idea {
|
|
module {
|
|
downloadJavadoc = true
|
|
downloadSources = true
|
|
}
|
|
}
|