apply plugin: 'org.jetbrains.kotlin.jvm'

description 'NetworkParameters signing tool'

dependencies {
    implementation project(':core')
    implementation project(':node-api')
    implementation project(':serialization')
    implementation project(':tools:cliutils')

    implementation "org.slf4j:jul-to-slf4j:$slf4j_version"
    implementation "org.apache.logging.log4j:log4j-slf4j2-impl:$log4j_version"
    implementation "com.jcabi:jcabi-manifests:$jcabi_manifests_version"
    implementation "com.typesafe:config:$typesafe_config_version"
    implementation "info.picocli:picocli:$picocli_version"
}

configurations.implementation.canBeResolved = true

jar {
    from(configurations.implementation.collect { it.isDirectory() ? it : zipTree(it) }) {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
    archiveBaseName = "netparams"
    manifest {
        attributes(
                'Main-Class': 'net.corda.netparams.NetParamsKt'
        )
    }
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

processResources {
    from file("$rootDir/config/dev/log4j2.xml")
    from file("$rootDir/node-api/src/main/resources/certificates/cordadevcakeys.jks")
}