corda/finance/build.gradle

apply plugin: 'kotlin'
// Java Persistence API support: create no-arg constructor
// see: http://stackoverflow.com/questions/32038177/kotlin-with-jpa-default-constructor-hell
apply plugin: 'kotlin-jpa'
apply plugin: CanonicalizerPlugin
apply plugin: 'net.corda.plugins.publish-utils'
apply plugin: 'net.corda.plugins.quasar-utils'

description 'Corda finance modules'

dependencies {
    compile project(':core')
    compile project(':node-schemas')

    testCompile project(':test-utils')
    testCompile project(path: ':core', configuration: 'testArtifacts')
    testCompile "junit:junit:$junit_version"

    // TODO: Upgrade to junit-quickcheck 0.8, once it is released,
    //       because it depends on org.javassist:javassist instead
    //       of javassist:javassist.
    testCompile "com.pholser:junit-quickcheck-core:$quickcheck_version"
    testCompile "com.pholser:junit-quickcheck-generators:$quickcheck_version"
}

configurations.testCompile {
    // Excluding javassist:javassist because it clashes with Hibernate's
    // transitive org.javassist:javassist dependency.
    // TODO: Remove this exclusion once junit-quickcheck 0.8 is released.
    exclude group: 'javassist', module: 'javassist'
}

configurations {
    testArtifacts.extendsFrom testRuntime
}

task testJar(type: Jar) {
    classifier "tests"
    from sourceSets.test.output
}

artifacts {
    testArtifacts testJar
}

jar {
    baseName 'corda-finance'
}

publish {
    name = jar.baseName
}