corda/core-deterministic/testing/data/build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm'
}

configurations {
    testData {
        canBeResolved = false
    }
}

dependencies {
    testImplementation project(':core')
    testImplementation project(':finance:workflows')
    testImplementation project(':node-driver')
    testImplementation project(path: ':core-deterministic:testing:verifier', configuration: 'runtimeArtifacts')

    testImplementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    testImplementation "org.jetbrains.kotlin:kotlin-reflect"

    testImplementation "junit:junit:$junit_version"

    testRuntimeOnly "org.junit.vintage:junit-vintage-engine:${junit_vintage_version}"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher:${junit_platform_version}"
}

tasks.named('jar', Jar) {
    enabled = false
}

def test = tasks.named('test', Test) {
    filter {
        // Running this class is the whole point, so include it explicitly.
        includeTestsMatching "net.corda.deterministic.data.GenerateData"
    }
    // force execution of these tests to generate artifacts required by other module (eg. VerifyTransactionTest)
    // note: required by Gradle Build Cache.
    outputs.upToDateWhen { false }
}

def testDataJar = file("$buildDir/test-data.jar")
artifacts {
    archives file: testDataJar, type: 'jar', builtBy: test
    testData file: testDataJar, type: 'jar', builtBy: test
}