corda/samples/irs-demo/cordapp/build.gradle

apply plugin: 'org.jetbrains.kotlin.jvm'
apply plugin: 'idea'
apply plugin: 'net.corda.plugins.quasar-utils'
apply plugin: 'net.corda.plugins.cordformation'
apply plugin: 'net.corda.plugins.cordapp'
apply plugin: 'application'

mainClassName = 'net.corda.irs.IRSDemo'

cordapp {
    targetPlatformVersion corda_platform_version.toInteger()
}

sourceSets {
    integrationTest {
        kotlin {
            compileClasspath += main.output + test.output
            runtimeClasspath += main.output + test.output
            srcDir file('src/integration-test/kotlin')
        }
    }
}

dependencies {
    if (System.getProperty('excludeShell') == null) {
        cordaDriver "net.corda:corda-shell:$corda_shell_version"
    }
    cordapp project(':finance:contracts')
    cordapp project(':finance:workflows')

    // Corda integration dependencies
    cordaRuntimeOnly project(path: ":node:capsule", configuration: 'runtimeArtifacts')
    cordaRuntimeOnly "org.slf4j:slf4j-simple:$slf4j_version"

    cordapp project(':samples:irs-demo:cordapp:contracts-irs')
    cordapp project(':samples:irs-demo:cordapp:workflows-irs')
}

def rpcUsersList = [
        ['username' : "user",
         'password' : "password",
         'permissions' : [
                 "StartFlow.net.corda.irs.flows.AutoOfferFlow\$Requester",
                 "StartFlow.net.corda.irs.flows.UpdateBusinessDayFlow\$Broadcast",
                 "StartFlow.net.corda.irs.api.NodeInterestRates\$UploadFixesFlow",
                 "InvokeRpc.vaultQueryBy",
                 "InvokeRpc.networkMapSnapshot",
                 "InvokeRpc.currentNodeTime",
                 "InvokeRpc.wellKnownPartyFromX500Name"
         ]]
]

def nodeTask = tasks.getByPath(':node:capsule:assemble')
configurations.cordaCordapp.canBeResolved = true
task deployNodes(type: net.corda.plugins.Cordform, dependsOn: ['jar', nodeTask]) {
    nodeDefaults{
        projectCordapp {
            deploy = false
        }
        cordapp project(':samples:irs-demo:cordapp:contracts-irs')
        cordapp project(':samples:irs-demo:cordapp:workflows-irs')
        runSchemaMigration = true
    }
    node {
        name "O=Notary Node,L=Zurich,C=CH"
        notary = [validating : true,
                  serviceLegalName: "O=Notary Service,L=Zurich,C=CH"
        ]
        p2pPort 10002
        rpcSettings {
            address("localhost:10003")
            adminAddress("localhost:10023")
        }
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
        extraConfig = ['h2Settings.address' : 'localhost:10024']
    }
    node {
        name "O=Bank A,L=London,C=GB"
        p2pPort 10005
        rpcSettings {
            address("localhost:10006")
            adminAddress("localhost:10026")
        }
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
        extraConfig = ['h2Settings.address' : 'localhost:10027']
    }
    node {
        name "O=Bank B,L=New York,C=US"
        p2pPort 10008
        rpcSettings {
            address("localhost:10009")
            adminAddress("localhost:10029")
        }
        cordapp "${project.group}:contracts:$corda_release_version"
        cordapp "${project.group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
        extraConfig = ['h2Settings.address' : 'localhost:10030']
    }
    node {
        name "O=Regulator,L=Moscow,C=RU"
        p2pPort 10011
        rpcSettings {
            address("localhost:10012")
            adminAddress("localhost:10032")
        }
        cordapp "${project.group}:contracts:$corda_release_version"
        cordapp "${project.group}:workflows:$corda_release_version"
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
        extraConfig = ['h2Settings.address' : 'localhost:10033']
    }

}

task prepareDockerNodes(type: net.corda.plugins.Dockerform, dependsOn: ['jar', nodeTask]) {
    nodeDefaults{
        cordapp project(':samples:irs-demo:cordapp:contracts-irs')
        cordapp project(':samples:irs-demo:cordapp:workflows-irs')
    }
    node {
        name "O=Notary Service,L=Zurich,C=CH"
        notary = [validating : true,
                  serviceLegalName: "O=Notary Service,L=Zurich,C=CH"
        ]
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
    }
    node {
        name "O=Bank A,L=London,C=GB"
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
    }
    node {
        name "O=Bank B,L=New York,C=US"
        cordapp "${project(":finance").group}:contracts:$corda_release_version"
        cordapp "${project(":finance").group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
    }
    node {
        name "O=Regulator,L=Moscow,C=RU"
        cordapp "${project.group}:contracts:$corda_release_version"
        cordapp "${project.group}:workflows:$corda_release_version"
        rpcUsers = rpcUsersList
        useTestClock true
    }
}

task integrationTest(type: Test, dependsOn: []) {
    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
}

// This fixes the "line too long" error when running this demo with windows CLI
// TODO: Automatically apply to all projects via a plugin
tasks.withType(CreateStartScripts).configureEach { task ->
    task.doLast {
        String text = task.windowsScript.text
        // Replaces the per file classpath (which are all jars in "lib") with a wildcard on lib
        text = text.replaceFirst(/(set CLASSPATH=%APP_HOME%\\lib\\).*/, { "${it[1]}*" })
        task.windowsScript.write text
    }
}

idea {
    module {
        downloadJavadoc = true
        downloadSources = true
    }
}