corda/samples/cordapp-configuration/build.gradle

apply plugin: 'kotlin'
apply plugin: 'idea'
apply plugin: 'net.corda.plugins.cordformation'

dependencies {
    if (System.getProperty('excludeShell') == null) {
        cordaDriver "net.corda:corda-shell:$corda_release_version"
    }
    runtimeOnly project(':node-api')
    // Cordformation needs a SLF4J implementation when executing the Network
    // Bootstrapper, but Log4J doesn't shutdown completely from within Gradle.
    // Use a much simpler SLF4J implementation here instead.
    cordaRuntime "org.slf4j:slf4j-simple:$slf4j_version"

    // Corda integration dependencies
    runtime project(path: ":node:capsule", configuration: 'runtimeArtifacts')

    cordapp project(':samples:cordapp-configuration:workflows')
}

def nodeTask = tasks.getByPath(':node:capsule:assemble')
def webTask = tasks.getByPath(':testing:testserver:testcapsule::assemble')
task deployNodes(type: net.corda.plugins.Cordform, dependsOn: ['jar', nodeTask, webTask]) {
    directory file("$buildDir/nodes")
    nodeDefaults {
        projectCordapp {
            deploy = false // TODO This is a bug, project cordapp should be disabled if no cordapp plugin is applied.
        }
        rpcUsers = [['username': "default", 'password': "default", 'permissions': [ 'ALL' ]]]
        cordapp project(':samples:cordapp-configuration:workflows')
        runSchemaMigration = true
    }
    node {
        name "O=Notary Node,L=Zurich,C=CH"
        notary = [validating : true,
                  serviceLegalName: "O=Notary Service,L=Zurich,C=CH"
        ]
        p2pPort 10002
        rpcSettings {
            port 10003
            adminPort 10004
        }
        extraConfig = ['h2Settings.address' : 'localhost:10005']
    }
    node {
        name "O=Bank A,L=London,C=GB"
        p2pPort 10006
        // This configures the default cordapp for this node
        cordapp (project(':samples:cordapp-configuration:workflows')) {
            config "someStringValue=test"
        }
        rpcSettings {
            port 10007
            adminPort 10008
        }
        extraConfig = ['h2Settings.address' : 'localhost:10009']
    }
    node {
        name "O=Bank B,L=New York,C=US"
        p2pPort 10010
        // This configures the default cordapp for this node
        cordapp (project(':samples:cordapp-configuration:workflows')){
            config project.file("src/config.conf")
        }
        rpcSettings {
            port 10011
            adminPort 10012
        }
        extraConfig = ['h2Settings.address' : 'localhost:10013']
    }
}