corda/samples/network-visualiser/build.gradle

buildscript {
    ext {
        springBootVersion = '1.5.7.RELEASE'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

// Spring Boot plugin adds a numerous hardcoded dependencies in the version much lower then Corda expects
// causing the problems in runtime. Those can be changed by manipulating above properties
// See https://github.com/spring-gradle-plugins/dependency-management-plugin/blob/master/README.md#changing-the-value-of-a-version-property
// unfortunately, this has to be repeated in every file using the spring boot plug-in as otherwise change in the order
// in which files are a processed changes the outcome of the processing (dependencies are listed after plug-ins, so the
// configuration of a dependency does not necessarily affect the plug-in application)
ext['artemis.version'] = "$artemis_version"
ext['hibernate.version'] = "$hibernate_version"


apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'idea'
apply plugin: 'application'
apply plugin: 'org.springframework.boot'
apply plugin: 'net.corda.plugins.quasar-utils'
apply plugin: 'us.kirchmeier.capsule'

// Spring Boot plugin have to be reimported, however it picks up the settings from irs-demo, so there is no need to
// reconfigure


// Warning: The network visualiser is not a Cordapp so please do not use it as an example of how
// to build a cordapp

dependencies {
    testCompile "junit:junit:$junit_version"

    // Corda integration dependencies
    compile project(path: ":node:capsule", configuration: 'runtimeArtifacts')
    compile project(path: ":webserver:webcapsule", configuration: 'runtimeArtifacts')
    compile project(':core')
    compile project(':finance')
    compile project(':node-driver')
    compile project(':finance')
    compile project(':samples:irs-demo')

    // GraphStream: For visualisation
    compileOnly "co.paralleluniverse:capsule:$capsule_version"
}

idea {
    module {
        downloadJavadoc = true // defaults to false
        downloadSources = true
    }
}

mainClassName = 'net.corda.netmap.NetworkMapVisualiser'

task deployVisualiser(type: FatCapsule) {
    applicationClass 'net.corda.netmap.NetworkMapVisualiser'
    reallyExecutable
    capsuleManifest {
        minJavaVersion = '1.8.0'
        javaAgents = [configurations.quasar.singleFile.name]
    }
}

jar {
    manifest {
        attributes(
                'Automatic-Module-Name': 'net.corda.samples.network.visualiser'
        )
    }
}