corda/node-api/build.gradle

apply plugin: 'kotlin'
apply plugin: 'net.corda.plugins.quasar-utils'
apply plugin: 'net.corda.plugins.publish-utils'
apply plugin: 'com.jfrog.artifactory'

description 'Corda node API'

dependencies {
    compile project(":core")
    compile project(":serialization")  // TODO Remove this once the NetworkBootstrapper class is moved into the tools:bootstrapper module
    compile project(':common-configuration-parsing') // TODO Remove this dependency once NetworkBootsrapper is moved into tools:bootstrapper
    compile project(':common-logging')

    compile "org.jetbrains.kotlin:kotlin-stdlib-jdk8:$kotlin_version"
    compile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"

    // TODO: remove the forced update of commons-collections and beanutils when artemis updates them
    compile "org.apache.commons:commons-collections4:${commons_collections_version}"
    compile "commons-beanutils:commons-beanutils:${beanutils_version}"
    compile("org.apache.activemq:artemis-core-client:${artemis_version}") {
        exclude group: 'org.jgroups', module: 'jgroups'
    }
    compile "org.apache.activemq:artemis-commons:${artemis_version}"

    compile "io.netty:netty-handler-proxy:$netty_version"

    // TypeSafe Config: for simple and human friendly config files.
    compile "com.typesafe:config:$typesafe_config_version"

    compile "org.apache.qpid:proton-j:$protonj_version"

    // SQL connection pooling library
    compile "com.zaxxer:HikariCP:$hikari_version"
    
    // ClassGraph: classpath scanning
    compile "io.github.classgraph:classgraph:$class_graph_version"

    // Kryo: object graph serialization.
    compile "com.esotericsoftware:kryo:$kryo_version"
    compile "de.javakaffee:kryo-serializers:$kryo_serializer_version"

    // For caches rather than guava
    compile "com.github.ben-manes.caffeine:caffeine:$caffeine_version"

    // For db migration
    compile "org.liquibase:liquibase-core:$liquibase_version"
    compile "com.fasterxml.jackson.core:jackson-databind:$jackson_version"
    runtime 'com.mattbertolini:liquibase-slf4j:2.0.0'

    // JDK11: required by Quasar at run-time
    runtime "com.esotericsoftware:kryo:$kryo_version"

    testImplementation "org.junit.jupiter:junit-jupiter-api:${junit_jupiter_version}"
    testImplementation "junit:junit:$junit_version"

    testRuntimeOnly "org.junit.vintage:junit-vintage-engine:${junit_vintage_version}"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junit_jupiter_version}"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher:${junit_platform_version}"
    // Unit testing helpers.
    testCompile "org.assertj:assertj-core:$assertj_version"
    testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
    testCompile project(':core-test-utils')

    compile ("org.apache.activemq:artemis-amqp-protocol:${artemis_version}") {
        // Gains our proton-j version from core module.
        exclude group: 'org.apache.qpid', module: 'proton-j'
        exclude group: 'org.jgroups', module: 'jgroups'
    }
}

configurations {
    testArtifacts.extendsFrom testRuntimeClasspath
}

task testJar(type: Jar) {
    classifier "tests"
    from sourceSets.test.output
}

artifacts {
    testArtifacts testJar
    publish testJar
}

jar {
    baseName 'corda-node-api'
}

publish {
    name jar.baseName
}