corda/tools/bootstrapper/build.gradle

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'net.corda.plugins.publish-utils'
apply plugin: 'com.jfrog.artifactory'

description 'Network bootstrapper'

dependencies {
    compile project(':node-api')
    compile project(':tools:cliutils')
    compile "info.picocli:picocli:$picocli_version"
    compile "org.slf4j:jul-to-slf4j:$slf4j_version"
    compile "org.apache.logging.log4j:log4j-slf4j-impl:$log4j_version"
    compile "com.jcabi:jcabi-manifests:$jcabi_manifests_version"
}

jar {
    from(configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }) {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
    from(project(':node:capsule').tasks['buildCordaJAR']) {
        rename 'corda-(.*)', 'corda.jar'
    }
    archiveName = "network-bootstrapper-${corda_release_version}.jar"
    manifest {
        attributes(
                'Automatic-Module-Name': 'net.corda.bootstrapper',
                'Main-Class': 'net.corda.bootstrapper.MainKt'
        )
    }
}

publish {
    name 'corda-tools-network-bootstrapper'
}