Implement 'resin local stop'

lib/actions/local/common.coffee

@@ -4,13 +4,23 @@ Docker = require('docker-toolbelt')
 form = require('resin-cli-form')
 chalk = require('chalk')
 
+filterOutSupervisorContainer = (container) ->
+	for name in container.Names
+		return false if name.includes('resin_supervisor')
+	return true
+
 module.exports =
 
-	selectContainerFromDevice: Promise.method (deviceIp) ->
+	filterOutSupervisorContainer: filterOutSupervisorContainer
+
+	selectContainerFromDevice: Promise.method (deviceIp, filterSupervisor = false) ->
 		docker = new Docker(host: deviceIp, port: 2375)
 
 		# List all containers, including those not running
 		docker.listContainersAsync(all: true)
+		.filter (container) ->
+			return true if not filterSupervisor
+			filterOutSupervisorContainer(container)
 		.then (containers) ->
 			if _.isEmpty(containers)
 				throw new Error("No containers found in #{deviceIp}")

lib/actions/local/index.coffee

@@ -21,3 +21,4 @@ exports.promote = require('./promote')
 exports.scan = require('./scan')
 exports.ssh = require('./ssh')
 exports.push = require('./push')
+exports.stop = require('./stop')

lib/actions/local/stop.coffee

@@ -0,0 +1,78 @@
+###
+Copyright 2017 Resin.io
+
+Licensed under the Apache License, Version 2.0 (the "License");
+you may not use this file except in compliance with the License.
+You may obtain a copy of the License at
+
+	 http://www.apache.org/licenses/LICENSE-2.0
+
+Unless required by applicable law or agreed to in writing, software
+distributed under the License is distributed on an "AS IS" BASIS,
+WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+See the License for the specific language governing permissions and
+limitations under the License.
+###
+
+# A function to reliably execute a command
+# in all supported operating systems, including
+# different Windows environments like `cmd.exe`
+# and `Cygwin` should be encapsulated in a
+# re-usable package.
+#
+module.exports =
+	signature: 'local stop [deviceIp]'
+	description: 'Stop a running container on a resinOS device'
+	help: '''
+
+		Examples:
+
+			$ resin local stop
+			$ resin local stop --app-name myapp
+			$ resin local stop --all
+			$ resin local stop 192.168.1.10
+			$ resin local stop 192.168.1.10 --app-name myapp
+	'''
+	options: [
+			signature: 'all'
+			boolean: true
+			description: 'stop all containers'
+	,
+			signature: 'app-name'
+			parameter: 'name'
+			description: 'name of container to stop'
+			alias: 'a'
+	]
+	action: (params, options, done) ->
+		Promise = require('bluebird')
+		chalk = require('chalk')
+		{ forms, config, ResinLocalDockerUtils } = require('resin-sync')
+		{ selectContainerFromDevice, filterOutSupervisorContainer } = require('./common')
+
+		Promise.try ->
+			if not params.deviceIp?
+				return forms.selectLocalResinOsDevice()
+			return params.deviceIp
+		.then (@deviceIp) =>
+			@docker = new ResinLocalDockerUtils(@deviceIp)
+
+			if options.all
+				# Only list running containers
+				return @docker.docker.listContainersAsync(all: false)
+				.filter(filterOutSupervisorContainer)
+				.then (containers) =>
+					Promise.map containers, ({ Names, Id }) =>
+						console.log(chalk.yellow.bold("* Stopping container #{Names[0]}"))
+						@docker.stopContainer(Id)
+
+			ymlConfig = config.load()
+			@appName = options['app-name'] ? ymlConfig['local_resinos']?['app-name']
+			@docker.checkForRunningContainer(@appName)
+			.then (isRunning) =>
+				if not isRunning
+					return selectContainerFromDevice(@deviceIp, true)
+
+				console.log(chalk.yellow.bold("* Stopping container #{@appName}"))
+				return @appName
+			.then (runningContainerName) =>
+				@docker.stopContainer(runningContainerName)

lib/app.coffee

@@ -132,6 +132,7 @@ capitano.command(actions.local.promote)
 capitano.command(actions.local.push)
 capitano.command(actions.local.ssh)
 capitano.command(actions.local.scan)
+capitano.command(actions.local.stop)
 
 update.notify()