Implement 'resin local logs'

lib/actions/local/common.coffee

@@ -0,0 +1,69 @@
+Promise = require('bluebird')
+_ = require('lodash')
+Docker = require('docker-toolbelt')
+form = require('resin-cli-form')
+chalk = require('chalk')
+
+module.exports =
+
+	selectContainerFromDevice: Promise.method (deviceIp) ->
+		docker = new Docker(host: deviceIp, port: 2375)
+
+		# List all containers, including those not running
+		docker.listContainersAsync(all: true)
+		.then (containers) ->
+			if _.isEmpty(containers)
+				throw new Error("No containers found in #{deviceIp}")
+
+			return form.ask
+				message: 'Select a container'
+				type: 'list'
+				choices: _.map containers, (container) ->
+					containerName = container.Names[0] or 'Untitled'
+					shortContainerId = ('' + container.Id).substr(0, 11)
+					containerStatus = container.Status
+
+					return {
+						name: "#{containerName} (#{shortContainerId}) - #{containerStatus}"
+						value: container.Id
+					}
+
+	pipeContainerStream: Promise.method ({ deviceIp, name, outStream, follow = false }) ->
+		docker = new Docker(host: deviceIp, port: 2375)
+
+		container = docker.getContainer(name)
+		container.inspectAsync()
+		.then (containerInfo) ->
+			return containerInfo?.State?.Running
+		.then (isRunning) ->
+			container.attachAsync
+				logs: not follow or not isRunning
+				stream: follow and isRunning
+				stdout: true
+				stderr: true
+		.then (containerStream) ->
+			containerStream.pipe(outStream)
+		.catch (err) ->
+			err = '' + err.statusCode
+			if err is '404'
+				return console.log(chalk.red.bold("Container '#{name}' not found."))
+			throw err
+
+	# A function to reliably execute a command
+	# in all supported operating systems, including
+	# different Windows environments like `cmd.exe`
+	# and `Cygwin` should be encapsulated in a
+	# re-usable package.
+	getSubShellCommand: (command) ->
+		os = require('os')
+
+		if os.platform() is 'win32'
+			return {
+				program: 'cmd.exe'
+				args: [ '/s', '/c', command ]
+			}
+		else
+			return {
+				program: '/bin/sh'
+				args: [ '-c', command ]
+			}

lib/actions/local/index.coffee

@@ -16,3 +16,4 @@ limitations under the License.
 
 exports.configure = require('./configure')
 exports.flash = require('./flash')
+exports.logs = require('./logs')

lib/actions/local/logs.coffee

@@ -0,0 +1,65 @@
+###
+Copyright 2017 Resin.io
+
+Licensed under the Apache License, Version 2.0 (the "License");
+you may not use this file except in compliance with the License.
+You may obtain a copy of the License at
+
+	 http://www.apache.org/licenses/LICENSE-2.0
+
+Unless required by applicable law or agreed to in writing, software
+distributed under the License is distributed on an "AS IS" BASIS,
+WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+See the License for the specific language governing permissions and
+limitations under the License.
+###
+
+# A function to reliably execute a command
+# in all supported operating systems, including
+# different Windows environments like `cmd.exe`
+# and `Cygwin` should be encapsulated in a
+# re-usable package.
+#
+module.exports =
+	signature: 'local logs [deviceIp]'
+	description: 'Get or attach to logs of a running container on a resinOS device'
+	help: '''
+
+		Examples:
+
+			$ resin local logs
+			$ resin local logs -f
+			$ resin local logs 192.168.1.10
+			$ resin local logs 192.168.1.10 -f
+			$ resin local logs 192.168.1.10 -f --app-name myapp
+	'''
+	options: [
+			signature: 'follow'
+			boolean: true
+			description: 'follow log'
+			alias: 'f'
+	,
+			signature: 'app-name'
+			parameter: 'name'
+			description: 'name of container to get logs from'
+			alias: 'a'
+	]
+	action: (params, options, done) ->
+		Promise = require('bluebird')
+		{ forms } = require('resin-sync')
+		{ selectContainerFromDevice, pipeContainerStream } = require('./common')
+
+		Promise.try ->
+			if not params.deviceIp?
+				return forms.selectLocalResinOsDevice()
+			return params.deviceIp
+		.then (@deviceIp) =>
+			if not options['app-name']?
+				return selectContainerFromDevice(@deviceIp)
+			return options['app-name']
+		.then (appName) =>
+			pipeContainerStream
+				deviceIp: @deviceIp
+				name: appName
+				outStream: process.stdout
+				follow: options['follow']

package.json

@@ -39,6 +39,7 @@
     "coffee-script": "~1.12.2",
     "columnify": "^1.5.2",
     "denymount": "^2.2.0",
+    "docker-toolbelt": "^1.3.3",
     "drivelist": "^5.0.16",
     "etcher-image-write": "^9.0.1",
     "inquirer": "^3.0.6",