From 212c06e5a2562496ae03c3cb772eb9f0cb279552 Mon Sep 17 00:00:00 2001
From: Juan Cruz Viotti <juanchiviotti@gmail.com>
Date: Mon, 22 Dec 2014 15:18:47 -0400
Subject: [PATCH] Decouple client code from server by creating key model

---
 lib/actions/keys.coffee       | 22 +++-------
 lib/resin/models/index.coffee |  1 +
 lib/resin/models/key.coffee   | 82 +++++++++++++++++++++++++++++++++++
 3 files changed, 88 insertions(+), 17 deletions(-)
 create mode 100644 lib/resin/models/key.coffee

diff --git a/lib/actions/keys.coffee b/lib/actions/keys.coffee
index 27673329..542e92c2 100644
--- a/lib/actions/keys.coffee
+++ b/lib/actions/keys.coffee
@@ -10,31 +10,24 @@ permissions = require('../permissions/permissions')
 errors = require('../errors/errors')
 
 exports.list = permissions.user ->
-	resin.server.get resin.settings.get('urls.keys'), (error, response, keys) ->
+	resin.models.key.getAll (error, keys) ->
 		errors.handle(error) if error?
+
 		log.out ui.widgets.table.horizontal keys, (key) ->
 			delete key.public_key
 			return key
 		, [ 'ID', 'Title' ]
 
 exports.info = permissions.user (params) ->
-
-	# TODO: We don't have a way to query a single ssh key yet.
-	# As a workaround, we request all of them, and filter
-	# the one we need. Fix once we have a better way.
-	resin.server.get resin.settings.get('urls.keys'), (error, response, keys) ->
+	resin.models.key.get params.id, (error, key) ->
 		errors.handle(error) if error?
-		key = _.findWhere(keys, id: params.id)
-		if not key?
-			errors.handle(new resin.errors.NotFound("key #{params.id}"))
 
 		key.public_key = '\n' + _.str.chop(key.public_key, resin.settings.get('sshKeyWidth')).join('\n')
 		log.out(ui.widgets.table.vertical(key, _.identity, [ 'ID', 'Title', 'Public Key' ]))
 
 exports.remove = permissions.user (params, options) ->
 	ui.patterns.remove 'key', options.yes, (callback) ->
-		url = _.template(resin.settings.get('urls.sshKey'), id: params.id)
-		resin.server.delete(url, callback)
+		resin.models.key.remove(params.id, callback)
 	, errors.handle
 
 exports.add = permissions.user (params) ->
@@ -48,12 +41,7 @@ exports.add = permissions.user (params) ->
 
 		(key, callback) ->
 			key = key.trim()
-
-			url = resin.settings.get('urls.keys')
-			data =
-				title: params.name
-				key: key
-			resin.server.post(url, data, callback)
+			resin.models.key.create(params.name, key, callback)
 
 	], (error) ->
 		return if not error?
diff --git a/lib/resin/models/index.coffee b/lib/resin/models/index.coffee
index 38fad673..410bb84d 100644
--- a/lib/resin/models/index.coffee
+++ b/lib/resin/models/index.coffee
@@ -1,4 +1,5 @@
 module.exports =
 	application: require('./application')
 	device: require('./device')
+	key: require('./key')
 	environmentVariables: require('./environment-variables')
diff --git a/lib/resin/models/key.coffee b/lib/resin/models/key.coffee
new file mode 100644
index 00000000..2d528be6
--- /dev/null
+++ b/lib/resin/models/key.coffee
@@ -0,0 +1,82 @@
+_ = require('lodash-contrib')
+server = require('../server/server')
+settings = require('../settings')
+errors = require('../errors/errors')
+
+# TODO: Do this with pinejs once it's exposed as an OData API
+
+# Get all ssh keys
+#
+# @param {Function} callback callback(error, keys)
+#
+# @throw {NotAny} Will throw if no keys were found
+#
+# @example Get all keys
+#		resin.models.key.getAll (error, keys) ->
+#			throw error if error?
+#			console.log(keys)
+#
+exports.getAll = (callback) ->
+	url = settings.get('urls.keys')
+	server.get url, (error, response, keys) ->
+		return callback(error) if error?
+
+		if _.isEmpty(keys)
+			return callback(new errors.NotAny('keys'))
+
+		return callback(null, keys)
+
+# Get a single ssh key
+#
+# @param {String, Number} id key id
+# @param {Function} callback callback(error, key)
+#
+# @throw {NotFound} Will throw if key was not found
+#
+# @example Find key
+#		resin.models.key.get 51, (error, key) ->
+#			throw error if error?
+#			console.log(key)
+#
+exports.get = (id, callback) ->
+	url = settings.get('urls.keys')
+	server.get url, (error, response, keys) ->
+		return callback(error) if error?
+
+		key = _.findWhere(keys, { id })
+
+		if not key?
+			return callback(new errors.NotFound("key #{id}"))
+
+		return callback(null, key)
+
+# Remove ssh key
+#
+# @param {String, Number} id key id
+# @param {Function} callback callback(error)
+#
+# @example Remove key
+#		resin.models.key.remove 51, (error) ->
+#			throw error if error?
+#
+exports.remove = (id, callback) ->
+	url = settings.get('urls.sshKey')
+	url = _.template(url, { id })
+	server.delete(url, _.unary(callback))
+
+# Create a ssh key
+#
+# @param {String} title key title
+# @param {String} key the public ssh key
+# @param {Function} callback callback(error)
+#
+# @todo We should return an id for consistency with the other models
+#
+# @example Create a key
+#		resin.models.key.create 'Main', 'ssh-rsa AAAAB....', (error) ->
+#			throw error if error?
+#
+exports.create = (title, key, callback) ->
+	url = settings.get('urls.keys')
+	data = { title, key }
+	server.post(url, data, _.unary(callback))